MSX Village forum

 
//-----------------------------------------------------------------------------
// Pattern Horizontal Flip. : Flip horizontaly a 8x8 Pixels pattern
// *pattern : Address of the 8x8 Pattern
// *buffer  : address of a 8 Bytes buffer
void PatternFlipH (void *Pattern, void *buffer) __naked  __sdcccall(0)  
{
 Pattern,buffer;
    __asm
 
                ;--------------------------------------------
                ;Flip horizontaly 8x8 Pattern 
                ;input:
                ;DE = 8x8 Pattern
                ;HL = 8 bytes buffer
                ;
                ; Fast byte Fliping routine by John Metcaff
                ;
                Push ix
                ld ix,#0
                add ix,sp
                ld e,4(ix)
                ld d,5(ix)
                ld l,6(ix)
                ld h,7(ix)
                pop ix
                ld b,#8
            Hloop:
               push hl
               ld a,(de)
               ld l,a
               rlca
               rlca
               xor l
               and #0xAA
               xor l
               ld l,a
               rlca
               rlca
               rlca
               rrc l
               xor l 
               and #0x66 
               xor l
 
               pop hl
               ld (hl),a
               inc hl
               inc de
               djnz Hloop
 
               ret
 
    __endasm;
}
 

 
 
//-----------------------------------------------------------------------------
// Pattern Vertical Flip. : Flip vertically a 8x8 Pixels pattern
// *pattern : Address of the 8x8 Pattern
// *buffer  : address of a 8 Bytes buffer
void PatternFlipV (void *Pattern, void *buffer) __naked __sdcccall(0)
{
 Pattern,buffer;
    __asm
 
                Push ix
                ld ix,#0
                add ix,sp
                ld e,4(ix)
                ld d,5(ix)
                ld l,6(ix)
                ld h,7(ix)
                pop ix
                ld bc,#7
                add hl,bc
                ld b,#8
            Vloop:
               ld a,(de)
               ld (hl),a
               inc de 
               dec hl
 
               djnz Vloop
 
               ret
 
    __endasm;
}
 

 
 
//-----------------------------------------------------------------------------
// Pattern Rotation : Rotate a 8x8 pixels pattern to 90° angles, right or left
// *pattern : Address of the 8x8 Pattern
// *buffer  : address of a 8 Bytes buffer
// direction : // 0 : Rotate to right    1: rotate to Left
 
void PatternRotation (void *Pattern, void *buffer, char rotation) __naked  __sdcccall(0)
{
    Pattern,buffer,rotation;
    __asm
           ;--------------------------------------------
            ;Rotate 8x8 Pattern 
            ;input:
            ;DE = 8x8 Pattern address  
            ;HL = 8 bytes buffer
            ;A   =  0 Clockwise (R)
            ;       1 equals Counter Clockwise (L)
            ;
            ;Output:
            ; Rotates a Pattern 90° left or right into a buffer
            ;
 
                Push ix
                ld ix,#0
                add ix,sp
                ld e,4(ix)
                ld d,5(ix)
                ld l,6(ix)
                ld h,7(ix)
                ld a,8(ix)
                pop ix
                ld c,#8
                and #1
 
                jr  z,rotbigloopR        ; If direction is right (=0)
 
            ; Left Rotation
            rotbigloopL:
               ld a,(de)
               inc de
               push hl
               ld b,#8
            rotloopL:
               rra
               rl (hl)
               inc hl
               djnz rotloopL
               pop hl
               dec c
               jr nz,rotbigloopL
               ret
 
            ; Right Rotation 
            rotbigloopR:
               ld a,(de)
               inc de
               push hl
               ld b,#8
            rotloopR:
               rla
               rr (hl)
               inc hl
               djnz rotloopR
               pop hl
               dec c
               jr nz,rotbigloopR
               ret
 
    __endasm;
}