MSX Village forum

La Place des Développeurs Conversion Jeux Msx1 en Msx2 Besoin d'aide pour convertir un jeux

nebulos Membre non connecté

Touriste

Rang

Avatar

Inscrit le : 25/10/2020 à 17h13

Messages: 29

Le 25/10/2020 à 17h25
Bonjour je cherche une ame charitable pour convertir mon jeux préféreé msx1 en jeux msx2 (jeux en basic)
ci joint le jeux en dsk et la source basic en txt
SCRAMB.txt

SCRAMBA.dsk


merci de votre aide
E-mail    
Sector28 Membre non connecté

Villageois

Rang

Avatar

Groupe : Shoutbox

Inscrit le : 12/05/2018 à 23h00

Messages: 492

Le 25/10/2020 à 19h15
Voici :siffle

Code :
1 '
2 '
3 '
4 '
5 '
6 '
7 '
8 '
9 '
10 CLEAR300,&HE000:KEYOFF:CLS:COLOR11,0,0:R=RND(-TIME):R=INT(16*RND(1))
15 POKE&HF036,R:DIMA(2),B(2),C(2),D(2),E(2),F(2),R$(5),SC(5),S$(5)
20 FORI=1TO5:SC(I)=0:S$(I)="0000000":R$(I)=".....":NEXTI:POKE&HF3DB,0
25 INPUT"NOMBRE DE MANETTES (0,1,2)";A
30 IFA=1THEND(1)=1:D(2)=1:GOTO40
35 IFA=2THEND(1)=1:D(2)=2
40 SCREEN1:PRINT"UN INSTANT SVP."
45 GOSUB325:GOSUB400
50 GOSUB1545:A=1:GOSUB305:IFJ=2THENA=2:GOSUB305
55 PLAY"L9O5CL18DEFGABO6C":IFJ=1THENZ=1:GOTO70
60 IFJ=2THENZ=Z+1:IFZ=3THENZ=1
65 IFV(1)=-1THENZ=2
70 LOCATE1,1:PRINTSTRING$(8," ");:GOSUB390:LOCATE8,9:PRINT"vwwwwwwwwwwp";:LOCATE8,10:PRINT"u JOUEUR";Z;"q";:LOCATE8,11:PRINT"tssssssssssr";
75 PUTSPRITE0,(120,112),15,0
80 PUTSPRITE1,(112,112),15,1
85 A$=MID$(STR$(B(Z)),2):B$=STRING$(5-LEN(A$),"0"):LOCATE21,1:PRINTB$+A$;:VPOKE&H1ADE,48+C(Z):LOCATE19,1:PRINTMID$(STR$(V(Z)),2);:LOCATE9,3:PRINTSTRING$(18,248);
90 POKE&HF04C,D(Z):FORK=0TOJ*1200:NEXTK:X=USR1(0):FORK=0TO12:SOUNDK,0:SOUND7,254:SOUND8,16:SOUND11,2:SOUND12,2:X=USR(0):X=PEEK(&HF056):IFX=0THEN140
95 PUTSPRITE0,(0,0),0
100 PUTSPRITE1,(0,0),0
105 BN=PEEK(&HF03A)+256*PEEK(&HF03B)-6250:IFBN>9THENBN=9
110 BEEP:X=USR1(0):M1$="L30N=U;":M2$="L30N=W;":LOCATE6,9:PRINT"vwwwwwwwwwwwwwwwp";:LOCATE6,10:PRINT"u BONUS";BN;"* 500 q";:LOCATE6,11:PRINT"tsssssssssssssssr";
115 C=2:FORI=1TO50:C=C+1:IFC>15THENC=2
120 U=45+C*2:W=U+4:PLAYM1$,M2$:IFC/2=INT(C/2)THENVPOKE8211,225ELSEVPOKE8211,17
125 VPOKE8217,C:FORK=0TO40:NEXTK,I
130 A=Z:GOSUB305:B(Z)=B(Z)+BN*50:IFB(Z)>49999!THENB(Z)=0:C(Z)=C(Z)+1
135 E(Z)=E(Z)-200:V(Z)=V(Z)+1:GOSUB315:POKE&HF04E,&HCF:POKE&HF04F,&H19:POKE&HF03A,&H7C:POKE&HF03B,&H18:POKE&HF054,&H9B:GOTO70
140 SOUND6,31:SOUND7,247:SOUND8,23:SOUND11,200:SOUND12,200:SOUND13,0
145 FORI=0TO20:VPOKE8217,31:VPOKE8219,31:VPOKE8220,31:VPOKE8221,31:FORK=0TO10:NEXTK:VPOKE8217,33:VPOKE8219,177:VPOKE8220,177:VPOKE8221,177:FORK=0TO10:NEXTK,I:FORI=0TO1500:NEXTI:BEEP
150 PUTSPRITE0,(0,0),0:PUTSPRITE1,(0,0),0:V(Z)=V(Z)-1:A=Z:GOSUB305:IFV(Z)=-1THEN175
155 RESTORE:GOSUB325
160 IFJ=1THENA=1:GOSUB315:GOTO55
165 A=Z+1:IFA=3THENA=1:IFV(1)=-1THENA=2
170 GOSUB315:GOTO55
175 T=T+1:LOCATE8,9:M1$="L8GFEDGFEDL4C":M2$="R2L8BAGFL4E":PLAYM1$,M2$:PRINT"vwwwwwwwwwwp";:LOCATE8,10:PRINT"u JOUEUR";Z;"q";:LOCATE8,11
180 PRINT"u          q";:LOCATE8,12:PRINT"uFIN DU JEUq";:LOCATE8,13:PRINT"tssssssssssr";: FORK=0TOJ*1000:NEXTK:IFJ-T<>0THEN155
185 W=B(1)*10+C(1)*50000!
190 IFW>SC(5)THENN=1:GOSUB215
195 IFJ=1THEN50
200 W=B(2)*10+C(2)*50000!
205 IFW>SC(5)THENN=2:GOSUB215
210 GOTO50
215 M1$="V5L8EDEGFEDL16F":M2$="V5L8CO3BO4CEDCO3GO4L16D":M3$="V5L8EGDO3BO4L2C":M4$="V5L4CO3GL2C"
220 CLS:C$="":LOCATE6,5:PRINT"JOUEUR";N;"BRAVO !";:LOCATE3,7:PRINT"VOTRE SCORE VOUS PLACE";:LOCATE4,9:PRINT"PARMI LES 5 PREMIERS";:LOCATE4,11:PRINT"INSCRIVEZ VOTRE NOM:";
225 LOCATE0,13:PRINT"v";:PRINTSTRING$(27,"w");:PRINT"p";:LOCATE0,14:PRINT"u";:FORI=65TO90:PRINTCHR$(I);:NEXTI:PRINT"*";:PRINT"q";:LOCATE0,15:PRINT"u"+STRING$(27," ")+"q";:LOCATE0,16:PRINT"t";:PRINTSTRING$(27,"s");:PRINT"r";:X=1
230 LOCATEX,15:PRINTCHR$(253);
235 FORI=0TO70:NEXTI:IFPLAY(0)=0THENPLAYM1$,M2$
240 S=STICK(D(N)):IFS<>0THENLOCATEX,15:PRINT" ";:GOTO250
245 T=STRIG(D(N)):IFT<>0THEN265ELSE235
250 IFS=7THENX=X-1:IFX<1THENX=27
255 IFS=3THENX=X+1:IFX>27THENX=1
260 GOTO230
265 IFX=27THEN280ELSEA$=CHR$(X+64):C$=C$+A$
270 LOCATE11+LEN(C$),18:PRINTA$;
275 IFLEN(C$)<5THEN230
280 PLAYM3$,M4$:FORI=1TO4:IFW>SC(I)THEN290
285 NEXTI
290 A$=MID$(STR$(W),2):B$=STRING$(7-LEN(A$),"0"):IFI=5THEN300
295 FORU=5TOI+1STEP-1:SC(U)=SC(U-1):S$(U)=S$(U-1):R$(U)=R$(U-1):NEXTU:S$(I)=B$+A$:SC(I)=W:R$(I)=LEFT$(C$,5)
300 RETURN
305 A(A)=PEEK(&HF038):B(A)=PEEK(&HF040)+256*PEEK(&HF041):C(A)=PEEK(&HF042):E(A)=PEEK(&HF05A)+256*PEEK(&HF05B):F(A)=PEEK(&HF05C)+256*PEEK(&HF05D)
310 RETURN
315 POKE&HF038,A(A):POKE&HF040,B(A)-256*INT(B(A)/256):POKE&HF041,INT(B(A)/256):POKE&HF042,C(A):POKE&HF05A,E(A)-256*INT(E(A)/256):POKE&HF05B,INT(E(A)/256):POKE&HF05C,F(A)-256*INT(F(A)/256):POKE&HF05D,INT(F(A)/256)
320 RETURN
325 FORI=&HF000TO&HF060:POKEI,0:NEXTI
330 FORI=1TO27:READB$,A$
335 A=VAL("&H"+A$):B=VAL("&H"+B$)
340 POKEB,A:NEXTI:RETURN
345 DATA F000,05,F002,0A,F00A,E5
350 DATA F00B,EC,F00C,EB,F00D,EA
355 DATA F00E,E9,F00F,E8,F010,E8
360 DATA F011,E8,F012,E7,F013,E6
365 DATA F014,E5,F015,E4,F016,E3
370 DATA F017,E2,F018,E1,F019,E0
375 DATA F03A,7C,F03B,18,F03C,05
380 DATA F03E,04,F04E,CF,F04F,19
385 DATA F054,9B,F05B,32,F05D,02
390 VPOKE8217,65:FORI=1640TO1647:VPOKEI,255:NEXTI:X=USR1(0):FORI=0TO7:FORK=0TO50:NEXTK:VPOKE1640+I,0:NEXTI:VPOKE8217,33
395 RETURN
400 SPRITE$(1)=CHR$(240)+CHR$(120)+CHR$(63)+CHR$(56)+CHR$(56)+CHR$(63)+CHR$(127)+CHR$(243)
405 SPRITE$(0)=CHR$(0)+CHR$(0)+CHR$(0)+CHR$(128)+CHR$(64)+CHR$(254)+CHR$(254)+CHR$(128)
410 FORI=1TO81:READB$
415 B=VAL("&H"+B$)
420 FORJ=0TO7:READA$
425 A=VAL("&H"+A$)
430 VPOKEB*8+J,A:NEXTJ,I
435 DATA 70,00,00,00,F8,08,08,08,08
440 DATA 71,08,08,08,08,08,08,08,08
445 DATA 72,08,08,08,08,F8,00,00,00
450 DATA 73,00,00,00,00,FF,00,00,00
455 DATA 74,10,10,10,10,1F,00,00,00
460 DATA 75,10,10,10,10,10,10,10,10
465 DATA 76,00,00,00,1F,10,10,10,10
470 DATA 77,00,00,00,FF,00,00,00,00
475 DATA DE,FF,FE,00,F8,F0,E0,00,80
480 DATA DF,FF,7F,00,1F,0F,07,00,01
485 DATA E0,7F,7F,7F,7F,7F,7F,7F,00
490 DATA E1,EF,FF,EF,EF,EF,D7,36,F9
495 DATA E2,FF,EF,E7,DB,DB,3D,DD,E2
500 DATA E3,FF,C7,BB,BB,9B,C7,0E,F1
505 DATA E4,FF,C3,DB,D2,B9,75,ED,F3
510 DATA E5,77,77,00,DD,DD,DD,00,77
515 DATA E6,E7,DB,DB,DB,D7,EF,D6,B9
520 DATA E7,F7,F7,EF,FF,FF,FF,FF,FF
525 DATA E8,7D,7D,7D,01,7D,7D,7D,7D
530 DATA E9,E7,DB,BD,03,BF,BF,DE,E1
535 DATA EA,E7,DB,D7,CF,D8,9B,5B,E7
540 DATA EB,F7,F7,F7,87,77,77,77,88
545 DATA EC,FE,FD,83,77,7B,7B,77,8F
550 DATA ED,01,03,00,0F,1F,3F,00,FF
555 DATA EE,80,C0,00,F0,F8,FC,00,FF
560 DATA C8,24,3C,42,42,FF,7E,3C,42
565 DATA C9,0C,1C,3C,7C,7C,04,0E,1B
570 DATA D0,3C,7E,C3,DF,C7,DF,5E,7E
575 DATA CB,18,18,18,3C,7E,18,3C,66
580 DATA CC,C3,3C,3C,3C,5A,99,3C,7E
585 DATA CD,00,00,00,00,00,00,00,00
590 DATA 31,02,02,02,02,06,06,06,06
595 DATA 32,FE,02,02,FE,C0,C0,C0,FE
600 DATA 33,FE,02,02,FE,06,06,06,FE
605 DATA 34,82,82,82,FE,06,06,06,06
610 DATA 35,FE,80,80,FE,06,06,06,FE
615 DATA 36,FE,80,80,FE,86,86,86,FE
620 DATA 37,FE,02,02,02,06,06,06,06
625 DATA 38,FE,82,82,FE,86,86,86,FE
630 DATA 39,FE,82,82,FE,06,06,06,FE
635 DATA 30,FE,82,82,82,86,86,86,FE
640 DATA A0,00,00,00,00,00,00,FF,FF
645 DATA A1,C0,C0,C0,C0,C0,C0,C0,C0
650 DATA A2,03,03,03,03,03,03,03,03
655 DATA A3,FF,FF,00,00,00,00,00,00
660 DATA A4,00,00,00,00,00,00,03,03
665 DATA A5,00,00,00,00,00,00,C0,C0
670 DATA A6,03,03,00,00,00,00,00,00
675 DATA A7,C0,C0,00,00,00,00,00,00
680 DATA AA,FE,80,80,FE,06,06,06,FE
685 DATA AB,FE,80,80,80,C0,C0,C0,FE
690 DATA AC,FE,82,82,FE,C4,C4,C6,C6
695 DATA AD,FE,82,82,FE,C2,C2,C2,C2
700 DATA AE,82,FE,9E,82,C2,C2,C2,C2
705 DATA AF,FC,84,84,FC,86,86,86,FE
710 DATA B0,80,80,80,80,C0,C0,C0,FE
715 DATA B1,FE,80,80,FC,C0,C0,C0,FF
720 DATA B3,00,00,00,00,00,00,00,00
725 DATA 9A,42,10,44,18,3D,88,10,42
730 DATA 9B,7E,83,BD,83,BD,BD,83,7E
735 DATA 9C,7E,C3,BD,BD,BD,BD,C3,7E
740 DATA 9D,7E,BD,9D,AD,B5,B9,BD,7E
745 DATA 9E,7E,BD,BD,BD,BD,BD,C3,7E
750 DATA 9F,7E,C1,BF,C3,FD,FD,83,7E
755 DATA F8,00,00,FF,FF,FF,FF,00,00
760 DATA F9,00,00,FC,FC,FC,FC,00,00
765 DATA FA,00,00,F0,F0,F0,F0,00,00
770 DATA FB,00,00,C0,C0,C0,C0,00,00
775 DATA FC,00,00,00,00,00,3F,00,00
780 DATA FD,20,70,F8,F8,20,20,20,20
785 DATA B8,00,00,00,00,00,00,FF,00
790 DATA B9,40,40,40,40,40,40,40,40
795 DATA BA,02,02,02,02,02,02,02,02
800 DATA BB,00,FF,00,00,00,00,00,00
805 DATA BC,00,00,00,00,00,00,C0,40
810 DATA BD,00,00,00,00,00,00,03,02
815 DATA BE,40,C0,00,00,00,00,00,00
820 DATA BF,02,03,00,00,00,00,00,00
825 DATA C0,42,42,42,42,42,42,42,42
830 DATA C1,00,00,00,00,00,00,C3,42
835 DATA C2,42,C3,00,00,00,00,00,00
840 FORI=&HE000TO&HE4CA:READA$
845 J=VAL("&H"+A$):DT=DT+J:POKEI,J:NEXTI:IFDT<>123163!THENBEEP:CLS:PRINT"ERREUR DANS LES DATAS":END
850 DEFUSR0=&HE3E0:DEFUSR1=&HE49F
855 RETURN
860 DATA 3E,00,F5,21,A4,18,E5,11,1A
865 DATA F0,01,19,00,CD,59,00,D1,1B
870 DATA D5,21,1A,F0,01,19,00,CD,5C
875 DATA 00,E1,F1,3C,FE,12,28,08,01
880 DATA 21,00,09,F5,E5,18,DC,2A,00
885 DATA F0,ED,5B,02,F0,E7,30,0B,2A
890 DATA 02,F0,2B,22,02,F0,3E,EE,18
895 DATA 63,ED,5B,00,F0,2A,02,F0,E7
900 DATA 30,0B,2A,02,F0,23,22,02,F0
905 DATA 3E,ED,18,4E,3A,04,F0,FE,00
910 DATA 28,06,3D,32,04,F0,18,12,3E
915 DATA 0A,CD,48,E1,32,00,F0,3E,14
920 DATA CD,48,E1,32,04,F0,18,B7,3E
925 DATA 1F,CD,48,E1,FE,01,20,04,3E
930 DATA C8,18,22,FE,02,20,04,3E,C9
935 DATA 18,1A,FE,03,20,04,3E,D0,18
940 DATA 12,FE,04,20,04,3E,CB,18,0A
945 DATA FE,05,20,04,3E,CC,18,02,3E
950 DATA CD,32,06,F0,3A,08,F0,FE,00
955 DATA 20,0E,3E,10,CD,48,E1,FE,0F
960 DATA 20,05,3E,10,32,08,F0,3A,08
965 DATA F0,FE,00,28,12,21,09,F0,47
970 DATA 23,10,FD,7E,21,DC,1A,CD,4D
975 DATA 00,21,08,F0,35,21,BC,1A,3A
980 DATA 02,F0,47,3E,E5,11,20,00,CD
985 DATA 4D,00,ED,52,10,F9,3A,06,F0
990 DATA FE,ED,20,09,19,CD,4D,00,ED
995 DATA 52,00,18,03,CD,4D,00,FE,EE
1000 DATA 28,01,23,06,04,3E,CD,ED,52
1005 DATA CD,4D,00,10,F9,ED,52,3A,38
1010 DATA F0,FE,00,CA,70,E1,3A,06,F0
1015 DATA FE,ED,20,0B,3E,DE,19,CD,4D
1020 DATA 00,00,00,00,18,0E,FE,EE,20
1025 DATA 04,3E,DF,18,03,3E,E5,00,CD
1030 DATA 4D,00,3A,02,F0,C6,06,47,3E
1035 DATA 11,98,47,3E,E5,ED,52,CD,4D
1040 DATA 00,10,F9,C9,D5,E5,16,00,5F
1045 DATA ED,5F,6F,3A,36,F0,AD,17,6F
1050 DATA ED,5F,AD,32,36,F0,CD,64,E1
1055 DATA 7C,3C,E1,D1,C9,21,00,00,29
1060 DATA CB,27,30,01,19,20,F8,C9,00
1065 DATA 00,00,00,00,00,3A,02,F0,C6
1070 DATA 05,47,3E,11,98,47,3E,CD,CD
1075 DATA 4D,00,ED,52,10,F9,3A,02,F0
1080 DATA 47,3E,10,98,CD,48,E1,47,19
1085 DATA 10,FD,3E,1A,CD,48,E1,47,3E
1090 DATA 1A,98,FE,00,20,04,3E,9B,18
1095 DATA 1D,FE,01,20,04,3E,9C,18,15
1100 DATA FE,02,20,04,3E,9D,18,0D,FE
1105 DATA 03,20,04,3E,9E,18,05,FE,04
1110 DATA C0,3E,9F,CD,4D,00,C9,3A,3C
1115 DATA F0,3D,32,3C,F0,FE,00,C0,3A
1120 DATA 3E,F0,32,3C,F0,2A,3A,F0,CD
1125 DATA 4A,00,FE,FB,20,13,3E,20,CD
1130 DATA 4D,00,2B,11,6A,18,E7,20,03
1135 DATA 3E,00,C9,22,3A,F0,C9,3C,C3
1140 DATA 4D,00,2A,40,F0,19,11,50,C3
1145 DATA E7,38,12,3A,42,F0,3C,32,42
1150 DATA F0,C6,30,21,FE,1A,CD,4D,00
1155 DATA 21,00,00,22,40,F0,DD,21,44
1160 DATA F0,11,10,27,CD,3D,E2,11,E8
1165 DATA 03,CD,3D,E2,11,64,00,CD,3D
1170 DATA E2,11,0A,00,CD,3D,E2,7D,C6
1175 DATA 30,DD,77,00,18,12,B7,06,FF
1180 DATA ED,52,04,30,FB,19,78,C6,30
1185 DATA DD,77,00,DD,23,C9,21,44,F0
1190 DATA 01,05,00,11,37,18,C3,5C,00
1195 DATA 3A,4C,F0,CD,D5,00,FE,00,C8
1200 DATA 2A,4E,F0,FE,01,20,07,11,20
1205 DATA 00,ED,52,18,3C,FE,02,20,07
1210 DATA 11,1F,00,ED,52,18,31,FE,03
1215 DATA 20,03,23,18,2A,FE,04,20,06
1220 DATA 11,21,00,19,18,20,FE,05,20
1225 DATA 06,11,20,00,19,18,16,FE,06
1230 DATA 20,06,11,1F,00,19,18,0C,FE
1235 DATA 07,20,03,2B,18,05,11,21,00
1240 DATA ED,52,22,4E,F0,11,00,18,ED
1245 DATA 52,E5,EB,21,20,00,CD,E6,31
1250 DATA 22,50,F0,3A,50,F0,87,87,87
1255 DATA 3D,21,00,1B,CD,4D,00,21,04
1260 DATA 1B,CD,4D,00,2A,50,F0,11,20
1265 DATA 00,CD,93,31,D1,EB,ED,52,22
1270 DATA 50,F0,3A,50,F0,87,87,87,21
1275 DATA 01,1B,CD,4D,00,DE,08,21,05
1280 DATA 1B,C3,4D,00,3A,4C,F0,CD,D8
1285 DATA 00,FE,00,C8,CD,B5,E4,2A,4E
1290 DATA F0,23,CD,4A,00,FE,CD,20,0F
1295 DATA 3E,FC,CD,4D,00,23,3A,52,F0
1300 DATA 3C,32,52,F0,18,EA,FE,DE,C8
1305 DATA FE,DF,C8,FE,ED,C8,FE,EE,C8
1310 DATA FE,A1,C8,FE,E5,C8,F5,3E,9A
1315 DATA CD,4D,00,F1,21,52,F0,34,FE
1320 DATA D0,CA,B4,E3,FE,C8,28,0C,FE
1325 DATA C9,28,08,FE,CB,28,04,FE,CC
1330 DATA 20,0B,CD,B9,E4,11,01,00,CD
1335 DATA FA,E1,18,11,F5,CD,BD,E4,11
1340 DATA 05,00,CD,FA,E1,F1,21,54,F0
1345 DATA BE,28,10,21,54,F0,36,9B,21
1350 DATA 23,18,3E,20,01,06,00,C3,56
1355 DATA 00,F5,DE,9A,47,21,23,18,23
1360 DATA 10,FD,F1,CD,4D,00,FE,9F,20
1365 DATA 07,F1,21,56,F0,36,01,C9,21
1370 DATA 54,F0,3C,77,C9,3A,52,F0,FE
1375 DATA 00,C8,ED,4B,52,F0,2A,4E,F0
1380 DATA 23,3E,CD,CD,56,00,3E,00,32
1385 DATA 52,F0,C9,2A,3A,F0,11,77,18
1390 DATA E7,38,12,21,77,18,3E,F8,01
1395 DATA 06,00,CD,56,00,21,7C,18,22
1400 DATA 3A,F0,C9,3E,F8,01,05,00,CD
1405 DATA 56,00,23,23,23,23,00,22,3A
1410 DATA F0,C9,CD,00,E0,3A,38,F0,FE
1415 DATA 00,28,08,21,BC,18,3E,E5,CD
1420 DATA 4D,00,CD,C9,E1,FE,00,20,06
1425 DATA 3E,00,32,56,F0,C9,2A,4E,F0
1430 DATA CD,4A,00,FE,CD,28,02,18,EE
1435 DATA 2B,CD,4A,00,FE,CD,28,02,18
1440 DATA E4,CD,5B,E2,2A,4E,F0,CD,4A
1445 DATA 00,FE,CD,28,02,18,D5,2B,CD
1450 DATA 4A,00,FE,CD,28,02,18,CB,CD
1455 DATA F8,E2,ED,4B,5A,F0,0B,78,FE
1460 DATA 00,20,FA,CD,9B,E3,21,E5,07
1465 DATA CD,4A,00,0F,0F,CD,4D,00,2A
1470 DATA 3A,F0,11,70,18,E7,38,10,3E
1475 DATA 0F,21,03,1B,CD,4D,00,21,07
1480 DATA 1B,CD,4D,00,18,04,3E,06,18
1485 DATA EE,ED,4B,5C,F0,0B,ED,43,5C
1490 DATA F0,78,FE,00,C2,DD,E3,3A,38
1495 DATA F0,FE,00,28,19,3E,00,32,38
1500 DATA F0,21,80,02,22,5C,F0,2A,5A
1505 DATA F0,11,A0,00,ED,52,22,5A,F0
1510 DATA C3,E0,E3,3E,01,32,38,F0,21
1515 DATA 80,01,18,E5,21,A3,18,06,12
1520 DATA 3E,CD,11,20,00,C5,01,1A,00
1525 DATA CD,56,00,C1,19,10,F5,C9,1E
1530 DATA 03,18,06,1E,02,18,02,1E,01
1535 DATA 3E,01,CD,02,11,1E,00,3E,0D
1540 DATA C3,02,11
1545 CLS
1550 VPOKE8206,65:VPOKE8215,65:VPOKE8216,65:VPOKE8212,65:VPOKE8213,65:VPOKE8214,65:VPOKE8217,65:VPOKE8218,145:VPOKE8211,225:VPOKE8223,97
1555 PRINTSTRING$(18," ")+CHR$(&HBD)+CHR$(&HB8)+CHR$(&HC1)+STRING$(6,&HB8)+CHR$(&HBC)
1560 PRINTSTRING$(9," ");:FORI=&HAATO&HB1:PRINTCHR$(I);:NEXTI:PRINT" "+CHR$(&HBA)+"0"+CHR$(&HC0)+STRING$(6,"0")+CHR$(&HB9)
1565 PRINTSTRING$(18," ")+CHR$(&HBF)+CHR$(&HBB)+CHR$(&HC2)+STRING$(6,&HBB)+CHR$(&HBE):PRINT" "+"ENERGIE:";:PRINTSTRING$(18,&HF8)
1570 PRINTCHR$(&HA4)+STRING$(26,&HA0)+CHR$(&HA5)
1575 FORI=0TO17:PRINTCHR$(&HA2)+STRING$(26,&HCD)+CHR$(&HA1):NEXTI
1580 PRINTCHR$(&HA6)+STRING$(26,&HA3)+CHR$(&HA7);
1585 LOCATE9,7:PRINT"CLASSEMENT";:FORI=1TO5:LOCATE3,I*2+8:PRINTI;"-   "+S$(I)+"  "+R$(I);:NEXTI
1590 M1$="VOL15O5EGCEDCFEG":PLAYM1$:TIME=0:J=1:LOCATE3,21
1595 PRINT"NOMBRE DE JOUEURS > 1";
1600 IFTIME>800THENTIME=0:PLAYM1$
1605 FORI=0TO70:NEXTI
1610 T=STICK(D(1)):IFT<>0THEN1620
1615 T=STRIG(D(1)):IFT=0THEN1600ELSE1630
1620 J=J+1:IFJ=3THENJ=1
1625 LOCATE22,21:PRINTJ;:FORI=1TOJ:BEEP:FORK=0TO30:NEXTK,I:GOTO1600
1630 RESTORE:GOSUB325
1635 T=0:Z=0:V(1)=3:V(2)=3
1640 RETURN


Le corps des nombres complexes n'est autre que le quotient du corps des polynômes en X à coefficients réels, par l'idéal engendré par le polynôme X²+1. Il est une extension de degré deux des réels... :)
   
nebulos Membre non connecté

Touriste

Rang

Avatar

Inscrit le : 25/10/2020 à 17h13

Messages: 29

Le 25/10/2020 à 19h24
Merci beaucoup Sector28_3
c'est génial, quelle réactivité.
ca marche impec!!
Mille merci ;-)
E-mail    
nebulos Membre non connecté

Touriste

Rang

Avatar

Inscrit le : 25/10/2020 à 17h13

Messages: 29

Le 25/10/2020 à 19h36
Petit bug le score ne se met pas a jour en temps reel et quand on veux ecrire bonus ca ne se rafraichit pas en cas de loupé
A priori c'est le haut de l'écran qui ne se raffraichit pas!
E-mail    
Sector28 Membre non connecté

Villageois

Rang

Avatar

Groupe : Shoutbox

Inscrit le : 12/05/2018 à 23h00

Messages: 492

Le 25/10/2020 à 19h44
C'est corrigé , recharge le prog!


Le corps des nombres complexes n'est autre que le quotient du corps des polynômes en X à coefficients réels, par l'idéal engendré par le polynôme X²+1. Il est une extension de degré deux des réels... :)
   
nebulos Membre non connecté

Touriste

Rang

Avatar

Inscrit le : 25/10/2020 à 17h13

Messages: 29

Le 25/10/2020 à 20h03
source : https://www.msxgamesworld.com/software.php?id=2835
a l'époque je l'avais eu sur cassette
E-mail    
nebulos Membre non connecté

Touriste

Rang

Avatar

Inscrit le : 25/10/2020 à 17h13

Messages: 29

Le 25/10/2020 à 20h13
super maintenant c'est parfait.
Bon boulot l'ami ;-)
E-mail    
nebulos Membre non connecté

Touriste

Rang

Avatar

Inscrit le : 25/10/2020 à 17h13

Messages: 29

Le 25/10/2020 à 20h14
Jeu publié au numéro 111 du magazine français Hebdogiciel.
E-mail    
nebulos Membre non connecté

Touriste

Rang

Avatar

Inscrit le : 25/10/2020 à 17h13

Messages: 29

Le 25/10/2020 à 20h54
Sinon pour info comment tu as fait cette conversion? tu utilises un logiciel spécifique? merci encore
E-mail    
TurboSEB Membre non connecté

Conseiller Municipal

Rang

Avatar

Groupe : compte ++ Groupe : Shoutbox

Inscrit le : 08/08/2010 à 20h57

Messages: 5525

Le 26/10/2020 à 00h35
J'ai vu une différence la moi :tea

Ligne 845 :
Entre IFDT<>127137!
Et IFDT<>123163!

Ça a un rapport avec la Ram disponible entre un Msx1 basic sans drive et un Msx2 avec drive ?

A quoi sert ce point d'exclamation au faite ?
Edité par TurboSEB Le 26/10/2020 à 00h58



MSX 1&2 + Moniteurs+divers (environ 0.70Tonnes)
   
Sector28 Membre non connecté

Villageois

Rang

Avatar

Groupe : Shoutbox

Inscrit le : 12/05/2018 à 23h00

Messages: 492

Le 26/10/2020 à 05h22
Lignes 860-1540, c'est du langage machine, il faut remplacer:
CALL $7D7 par CALL $4A
CALL $7CD par CALL $4D
CALL $815 par CALL $56
CALL $744 par CALL $5C

La valeur de DT dépend du contenu des lignes 860 à 1540

Le "!" :
DT% : variable entière (defint)
DT! : variable réelle simple précision (defsng)
DT#: variable réelle double précision (defdbl), c'est le type par défaut.
DT$: variable alphanumérique.
DT: type par défaut.

Le type par défaut peut être modifié par DEFINT,DEFDBL,DEFSNG,DEFSTR.
exemple:
DEFSTR S : S="Hello"


Le corps des nombres complexes n'est autre que le quotient du corps des polynômes en X à coefficients réels, par l'idéal engendré par le polynôme X²+1. Il est une extension de degré deux des réels... :)
   
TurboSEB Membre non connecté

Conseiller Municipal

Rang

Avatar

Groupe : compte ++ Groupe : Shoutbox

Inscrit le : 08/08/2010 à 20h57

Messages: 5525

Le 26/10/2020 à 07h09
Comme mon niveau en programmation est ridicule, j'essai de comprendre dans les principes de base de ce programme, notamment les différentes boucles de data, j'ai bien compris qu'il y avait différentes données contenues dans les datas pour écrire dans différents segments de mémoires, boucles POKE, ca doit étre en RAM et boucle VPOKE, en VRAM, mais je ne sais pas a quoi correspondent les différents Data A, B, I, J,.... Ça doit être pour dessiner les décors entre autres. :tea

D'habitude les programmeurs laissent des commentaires ou des pense bête ^^

C'etait quoi les critères qui ont nécessités une conversion du Msx1 vers le Msx2. Pour moi je sais qu'il y a une différence de RAM disponible pour le Basic au boot, du au disc drive, mais à part cela, je ne vois pas ce qui pouvait empêcher ce programme de fonctionné sur Msx2 :) Edité par TurboSEB Le 26/10/2020 à 07h16



MSX 1&2 + Moniteurs+divers (environ 0.70Tonnes)
   
nebulos Membre non connecté

Touriste

Rang

Avatar

Inscrit le : 25/10/2020 à 17h13

Messages: 29

Le 26/10/2020 à 07h49
Je souhaitais faire une conversion car mon jeux ne marchais pas sur mon mister fpga msx1 ainsi que mon msx2
maintenant il fonctionne sur le core msx2 du mister et sur le msx2
E-mail    
Sector28 Membre non connecté

Villageois

Rang

Avatar

Groupe : Shoutbox

Inscrit le : 12/05/2018 à 23h00

Messages: 492

Le 26/10/2020 à 08h01
Il ne s'agit pas d'une conversion, mais d'un déboguage.
Le programmeur n'a pas respecté les règles qui garantissent la compatibilité msx.

D'ailleurs, une conversion msx1 en msx2, cela n'a aucun sens.


Le corps des nombres complexes n'est autre que le quotient du corps des polynômes en X à coefficients réels, par l'idéal engendré par le polynôme X²+1. Il est une extension de degré deux des réels... :)
   
TurboSEB Membre non connecté

Conseiller Municipal

Rang

Avatar

Groupe : compte ++ Groupe : Shoutbox

Inscrit le : 08/08/2010 à 20h57

Messages: 5525

Le 26/10/2020 à 08h22
Oui mais le Msx2 n'existait peut-être pas aussi a l'epoque :)

Edit : Hebdogiciel N°111, 25 Novembre 1985, page 33, programme SCRAMBLE, pas vue de commentaires du programmeur :tea

Alors, c'était quoi ce bug au juste ?

Ah y veux pas cracher le morceau ! :lol Edité par TurboSEB Le 26/10/2020 à 08h37



MSX 1&2 + Moniteurs+divers (environ 0.70Tonnes)
   
Répondre
Vous n'êtes pas autorisé à écrire dans cette catégorie