MSX Village forum

 
; lecture clavier et joystick
CLVJOY:
    LD   E,08Fh ; 10001111
;Bit 0 = Contrôle de la broche 6 du port général 1*
;Bit 1 = Contrôle de la broche 7 du port général 1*
;Bit 2 = Contrôle de la broche 6 du port général 2*
;Bit 3 = Contrôle de la broche 7 du port général 2*
;    * Mis à 1 pour utiliser comme entrée le port général (lecture).
;Bit 4 = Contrôle de la broche 8 du port général 1 (0 pour mode joystick standard)
;Bit 5 = Contrôle de la broche 8 du port général 2 (0 pour mode joystick standard)
;Bit 6 = Sélection du port général lisible via le registre 14 (0 pour port 1)
;Bit 7 = Contrôle de la LED de la touche "code" ou "Kana" (1 pour éteindre)
    LD   A,00Fh ; dans le port 15 (sortie)
    CALL WRTPSG ; du PSG
    LD   A,00Eh ;
    DI
    CALL RDPSG ; lecture du registre 14 (port joystick)
; logique négative : 0 = actionné
;Bit 0 = état de la broche 1 du port général sélectionné (Haut)
;Bit 1 = état de la broche 2 du port général sélectionné (Bas)
;Bit 2 = état de la broche 3 du port général sélectionné (Gauche)
;Bit 3 = état de la broche 4 du port général sélectionné (Droite)
;Bit 4 = état de la broche 6 du port général sélectionné (Bouton 1)
;Bit 5 = état de la broche 7 du port général sélectionné (Bouton 2)
;Bit 6 = 1 pour JIS, 0 pour Kana (valable seulement pour les MSX japonais)
;Bit 7 = CASRD (Signal de lecture sur cassette)
    EI
    CPL  ; complément
    AND  03Fh ; 00111111 ne conserve que les informations joystick
    PUSH AF   ; sauvegarde
    LD   A,007h ; lecture ligne 7 clavier
    CALL SNSMAT ; b7=RET b6=SELECT b5=BS b4=STOP b3=TAB b2=ESC b1=F5/F10 b0=F4/F9
    CPL
    RRCA ; rotation à droite : b6=RET b5=SELECT b4=BS b3=STOP b2=TAB b1=ESC b0=F5/F10 b7=F4/F9
    AND  020h ; ne conserve que le b5=SELECT
    LD   E,A   ; sauve dans E
    LD   A,008h  ; b7=droite b6=bas b5=haut b4=gauche b3=SUP b2=INS b1=Home/EFF b0=SPACE
    CALL SNSMAT  ; lecture ligne 8 clavier
    CPL
    RRCA
    RRCA ; 2xrotation à droite : b5=droite b4=bas b3=haut b2=gauche b1=SUP b0=INS b7=Home/EFF b6=SPACE
    LD   B,A   ; sauvegarde dans B
    AND  004h ; ne conserve que le b2=gauche
    OR   E    ; ajoute info SELECT
    LD   C,A ; sauve dans C b2=gauche b5=SELECT
    LD   A,B
    RRCA
    RRCA ; 2xrotation à droite : b3=droite b2=bas b1=haut b0=gauche b7=SUP b6=INS b5=Home/EFF b4=SPACE
    LD   B,A ; sauve dans B
    AND  018h ; conserve b3=droite et b4=SPACE
    OR   C   ; ajoute infos b2=gauche b5=SELECT
    LD   C,A ; sauve dans C
    LD   A,B ; recupère b3=droite b2=bas b1=haut b0=gauche b7=SUP b6=INS b5=Home/EFF b4=SPACE
    RRCA     ; rotation à droite : b2=droite b1=bas b0=haut b7=gauche b6=SUP b5=INS b4=Home/EFF b3=SPACE
    AND  003h ; conserve b1=bas b0=haut
    OR   C   ; b0=haut b1=bas b2=gauche b3=droite b4=SPACE b5=SELECT   
    POP  BC ; récupère infos joystick dans B
    OR   B  ; combine les actions clavier et joystick b0=haut b1=bas b2=gauche b3=droite b4=bouton1/SPACE b5=bouton2/SELECT
    RET